1 files changed, 181 insertions, 0 deletions
diff --git a/test/web/activity_pub/transmogrifier_test.exs b/test/web/activity_pub/transmogrifier_test.exs
new file mode 100644
index 000000000..96dd63057
--- /dev/null
+++ b/test/web/activity_pub/transmogrifier_test.exs
@@ -0,0 +1,181 @@
+defmodule Pleroma.Web.ActivityPub.TransmogrifierTest do
+  use Pleroma.DataCase
+  alias Pleroma.Web.ActivityPub.Transmogrifier
+  alias Pleroma.Activity
+  alias Pleroma.User
+  alias Pleroma.Repo
+  import Ecto.Query
+
+  import Pleroma.Factory
+  alias Pleroma.Web.CommonAPI
+
+  describe "handle_incoming" do
+    test "it ignores an incoming notice if we already have it" do
+      activity = insert(:note_activity)
+
+      data = File.read!("test/fixtures/mastodon-post-activity.json")
+      |> Poison.decode!
+      |> Map.put("object", activity.data["object"])
+
+      {:ok, returned_activity} = Transmogrifier.handle_incoming(data)
+
+      assert activity == returned_activity
+    end
+
+    test "it fetches replied-to activities if we don't have them" do
+      data = File.read!("test/fixtures/mastodon-post-activity.json")
+      |> Poison.decode!
+
+      object = data["object"]
+      |> Map.put("inReplyTo", "https://shitposter.club/notice/2827873")
+
+      data = data
+      |> Map.put("object", object)
+
+      {:ok, returned_activity} = Transmogrifier.handle_incoming(data)
+
+      assert Activity.get_create_activity_by_object_ap_id("tag:shitposter.club,2017-05-05:noticeId=2827873:objectType=comment")
+    end
+
+    test "it works for incoming notices" do
+      data = File.read!("test/fixtures/mastodon-post-activity.json") |> Poison.decode!
+
+      {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
+      assert data["id"] == "http://mastodon.example.org/users/admin/statuses/99512778738411822/activity"
+      assert data["context"] == "tag:mastodon.example.org,2018-02-12:objectId=20:objectType=Conversation"
+      assert data["to"] == ["https://www.w3.org/ns/activitystreams#Public"]
+      assert data["cc"] == [
+        "http://mastodon.example.org/users/admin/followers",
+        "http://localtesting.pleroma.lol/users/lain"
+      ]
+      assert data["actor"] == "http://mastodon.example.org/users/admin"
+
+      object = data["object"]
+      assert object["id"] == "http://mastodon.example.org/users/admin/statuses/99512778738411822"
+
+      assert object["to"] == ["https://www.w3.org/ns/activitystreams#Public"]
+      assert object["cc"] == [
+        "http://mastodon.example.org/users/admin/followers",
+        "http://localtesting.pleroma.lol/users/lain"
+      ]
+      assert object["actor"] == "http://mastodon.example.org/users/admin"
+      assert object["attributedTo"] == "http://mastodon.example.org/users/admin"
+      assert object["context"] == "tag:mastodon.example.org,2018-02-12:objectId=20:objectType=Conversation"
+      assert object["sensitive"] == true
+    end
+
+    test "it works for incoming follow requests" do
+      user = insert(:user)
+      data = File.read!("test/fixtures/mastodon-follow-activity.json") |> Poison.decode!
+      |> Map.put("object", user.ap_id)
+
+      {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
+
+      assert data["actor"] == "http://mastodon.example.org/users/admin"
+      assert data["type"] == "Follow"
+      assert data["id"] == "http://mastodon.example.org/users/admin#follows/2"
+      assert User.following?(User.get_by_ap_id(data["actor"]), user)
+    end
+
+    test "it works for incoming likes" do
+      user = insert(:user)
+      {:ok, activity} = CommonAPI.post(user, %{"status" => "hello"})
+
+      data = File.read!("test/fixtures/mastodon-like.json") |> Poison.decode!
+      |> Map.put("object", activity.data["object"]["id"])
+
+      {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
+
+      assert data["actor"] == "http://mastodon.example.org/users/admin"
+      assert data["type"] == "Like"
+      assert data["id"] == "http://mastodon.example.org/users/admin#likes/2"
+      assert data["object"] == activity.data["object"]["id"]
+    end
+
+    test "it works for incoming announces" do
+      data = File.read!("test/fixtures/mastodon-announce.json") |> Poison.decode!
+
+      {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
+
+      assert data["actor"] == "http://mastodon.example.org/users/admin"
+      assert data["type"] == "Announce"
+      assert data["id"] == "http://mastodon.example.org/users/admin/statuses/99542391527669785/activity"
+      assert data["object"] == "http://mastodon.example.org/users/admin/statuses/99541947525187367"
+
+      assert Activity.get_create_activity_by_object_ap_id(data["object"])
+    end
+
+    test "it works for incoming announces with an existing activity" do
+      user = insert(:user)
+      {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
+
+      data = File.read!("test/fixtures/mastodon-announce.json")
+      |> Poison.decode!
+      |> Map.put("object", activity.data["object"]["id"])
+
+      {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
+
+      assert data["actor"] == "http://mastodon.example.org/users/admin"
+      assert data["type"] == "Announce"
+      assert data["id"] == "http://mastodon.example.org/users/admin/statuses/99542391527669785/activity"
+      assert data["object"] == activity.data["object"]["id"]
+
+      assert Activity.get_create_activity_by_object_ap_id(data["object"]).id == activity.id
+    end
+  end
+
+  describe "prepare outgoing" do
+    test "it turns mentions into tags" do
+      user = insert(:user)
+      other_user = insert(:user)
+
+      {:ok, activity} = CommonAPI.post(user, %{"status" => "hey, @#{other_user.nickname}, how are ya? #2hu"})
+
+      {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
+      object = modified["object"]
+
+      expected_mention = %{
+        "href" => other_user.ap_id,
+        "name" => "@#{other_user.nickname}",
+        "type" => "Mention"
+      }
+
+      expected_tag = %{
+        "href" => Pleroma.Web.Endpoint.url <> "/tags/2hu",
+        "type" => "Hashtag",
+        "name" => "#2hu"
+      }
+
+      assert Enum.member?(object["tag"], expected_tag)
+      assert Enum.member?(object["tag"], expected_mention)
+    end
+
+    test "it adds the sensitive property" do
+      user = insert(:user)
+
+      {:ok, activity} = CommonAPI.post(user, %{"status" => "#nsfw hey"})
+      {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
+
+      assert modified["object"]["sensitive"]
+    end
+
+    test "it adds the json-ld context and the conversation property" do
+      user = insert(:user)
+
+      {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
+      {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
+
+      assert modified["@context"] == "https://www.w3.org/ns/activitystreams"
+      assert modified["object"]["conversation"] == modified["context"]
+    end
+
+    test "it sets the 'attributedTo' property to the actor of the object if it doesn't have one" do
+      user = insert(:user)
+
+      {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
+      {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
+
+      assert modified["object"]["actor"] == modified["object"]["attributedTo"]
+    end
+  end
+end